Předmět Autor Datum
v perlu: www.perlmonks.org prasárna v AutoIt: http://www.edugeek.net/forums/windows/11358-set-fi ref…
touchwood 08.06.2009 13:06
touchwood
cus, no tohle jsem vygooglil taky, ale problem s FF je, ze jmeno adresare u profilu je nahodne a to…
Zabak1 09.06.2009 08:48
Zabak1
A co group policy? Myslím že v ADM šablonách pro firefox nastavení proxy je.
Vladimir 09.06.2009 10:38
Vladimir
problem je ze nemam Windows domenovej radic, abych to mohl resit centralne, je jen jakysi login skri…
Zabak1 09.06.2009 12:28
Zabak1
ano, ale to je takový problém si adresář zjistit v rámci toho VBS? Když vydržíš, podívám se doma, u…
touchwood 09.06.2009 15:49
touchwood
nedalo mi to a napsal jsem to celé. Stačí uložit a spustit (samozřejmě je nutno v sekci pro Admina m…
touchwood 09.06.2009 19:57
touchwood
super diky moc, mam co ucit :-) poslední
Zabak1 10.06.2009 11:32
Zabak1

nedalo mi to a napsal jsem to celé. Stačí uložit a spustit (samozřejmě je nutno v sekci pro Admina modifikovat parametry proxy).

Dim fso, f, sf, folder, file, cil, exitus, ss, ssline
Dim http_proxy, http_proxy_port, proxy_type, no_proxy_for
Dim direktivy(3)
Dim hodnoty(3)

' Zde si admin nastaví svá nastavení pro svou síť
http_proxy = "proxy.mojefirma.cz"
http_proxy_port = "3128"
proxy_type = "1"
no_proxy_for = "localhost, 127.0.0.1, www.mojefirma.cz,"

' Vytvoříme si stringy s hnusnými úvozovkami a jiné proměnné
exitus = 0
direktivy(0) = "network.proxy.http"
direktivy(1) = "network.proxy.http_port"
direktivy(2) = "network.proxy.no_proxies_on"
direktivy(3) = "network.proxy.type"
hodnoty(0) = "user_pref("+ Chr(34) + "network.proxy.http"+ Chr(34)+ ", "+ Chr(34)+ http_proxy + Chr(34) + ");"
hodnoty(1) = "user_pref("+ Chr(34) + "network.proxy.http_port"+ Chr(34)+ ", " + http_proxy_port + ");"
hodnoty(2) = "user_pref("+ Chr(34) + "network.proxy.no_proxies_on"+ Chr(34)+ ", "+ Chr(34)+ no_proxy_for + Chr(34) + ");"
hodnoty(3) = "user_pref("+ Chr(34) + "network.proxy.type"+ Chr(34)+ ", "+ proxy_type + ");"

'
'sosneme si cestu
'
Set WshShell = WScript.CreateObject("WScript.Shell")
path = WshShell.ExpandEnvironmentStrings("%appdata%") & "\Mozilla\Firefox\Profiles"

'
'Test existence profilu
'
Set objFSO = CreateObject("Scripting.FileSystemObject")
If Not objFSO.FolderExists(path) Then WScript.Quit

'
'sosneme si adresar profilu
' 
Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.GetFolder(path)
Set sf = f.SubFolders
  	For Each folder in sf
		if Right(folder.name,8) = ".default" then cil = folder.name
	next
'
'Zkontrolujeme existenci radku, ktery chceme pridat, aby nebyly duplicity atd. pri dalsich bezich a smazeme je
'
set file = fso.OpenTextFile(path & "\" & cil & "\" & "prefs.js",1,0)
ss = file.ReadAll
file.close 

ssline = Split(ss, vbNewLine)

Set file = fso.OpenTextFile(path & "\" & cil & "\" & "prefs.js",2,0)

For Each radek In ssline
	For each retezec in direktivy
		if InStr(radek, retezec) > 0 Then 
			exitus = 1			
		End If
	Next
	If exitus = 0 Then 
			file.WriteLine radek
		Else	
			exitus = 0
	End If
Next
'
'Zapiseme to co chceme, tj. "nase" nastaveni Proxy :-)
'Skript pro návrat zpět na původní konfiguraci bez proxy nebude mít následující řádky, jinak bude totožný
'
For each radek in hodnoty	
	file.WriteLine(radek)
Next
file.close

edit: mě to psaní takových pitomých skriptů prostě baví :-)

Zpět do poradny Odpovědět na původní otázku Nahoru