Excel - percentá resp. zobrazenie vysledku v bunke povodnej hodnoty

Spustíš makro:

Sub Macro1()
 Range("A1").Value = Range("A1").Value - (Range("A1").Value * Range("A6").Value)
End Sub

Nedalo by sa ti to ukázať na konkrétnom príklade resp. v ukážkovom súbore?

Jinak než makrem mě to nenapadá.

No toto nie je zlé ale čo v prípade že tú cenu chcem zmeniť napr. na pôvodnú? Keď tam zadám 0 percent neurobí to nič.
Skôr by som potreboval spôsob kde môžem "operovať" s percentami tak ako si mi ukázál, ale v prípade že sa potrebujem dostať na počiatočnú hodnotu tak po zadaní 0 percent mi ju ukáže. Proste aby bola v "pamati" stále ta mnou zadaná hodnota vtej bunke.

Ďakujem aj za túto pomoc!

Doplnis do makra podmienku if A6 = 0 then A1 = 55. Syntax nie je presna, ja makra nerobim, ale v principe ti to tam staci.

Ahoj,

lenže to číslo nebude stále 55 €

Je potřeba mít jasno v tom, pro kolik čísel toto řešíme. Prakticky omezeni nejsme, můžem vytvořit třeba pole a do toho ta čísla naládovat, i kdyby jich bylo "milion".
Čím víc se ta čísla schovají, tím hůř se budou kdykoliv později upravovat a přepisovat. Opravdu není možné si je např. "odložit" na jiný list sešitu (nebo i do jiného sešitu)?

mam jasne akurat dve bunky! A1 - kde zadavam lubovolne cislo resp. hodnotu v €
a druhu bunku kde znova zadavam lubovolne percenta o ktore chcem tuto cenu ponizit. Ale ked zadam hodnotu percent=0 tak aby mi tam skocila povodna hodnota by som potreboval. Nieco ako cennikova cena s ktorou chcem potom kalkulovat.

Takto sa s Excelom nepracuje, zbytočne si komplikuješ život.

Ufff, takže takto?

Presne!

len mám jeden problémik a to je nasledovne.
Pri otvorení súboru mi to dáva chybu:
Run-time error "1004":
Method "range"of object "_Global" failed

pocítať to počíta, ukladať to ukladá ale niekde je ešte zádrheľ..

Tak klikni na debug a uvidíš kam tě to zavede.
Pravděpodobně bude zrada někde v ThisWorkbook

To už som medzičasom vyriešil ano bolo to tam ale aký zápis bude pri viacerých takýchto kombinácii?

môžem to zapísať aj takto?

do hárku zadefinovať:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Target.Worksheet.Range("P16")) Is Nothing Then CalculatePercentage
    If Not Intersect(Target, Target.Worksheet.Range("M16")) Is Nothing Then SetNewBase
    
    If Not Intersect(Target, Target.Worksheet.Range("P17")) Is Nothing Then CalculatePercentage
    If Not Intersect(Target, Target.Worksheet.Range("M17")) Is Nothing Then SetNewBase
End Sub

a do module1 zadefinovať:

Public BaseNumber As Variant

Sub CalculatePercentage()
    Application.EnableEvents = False
    Range("M16").Value = BaseNumber - (BaseNumber * Range("P16").Value)
    Application.EnableEvents = True
    If Range("P16").Value = 0 Then Range("M16").Value = BaseNumber

    Application.EnableEvents = False
    Range("M17").Value = BaseNumber - (BaseNumber * Range("P17").Value)
    Application.EnableEvents = True
    If Range("P17").Value = 0 Then Range("M17").Value = BaseNumber
End Sub

Sub SetNewBase()
    BaseNumber = Range("M16").Value
End Sub
Sub SetNewBase1()
    BaseNumber = Range("M17").Value
End Sub

Evidentne keďže sa pýtam to nie je správne zapísané ale neviem kde robím chybu.

Nechápem, prečo nechceš pracovať s Excelom normálnym spôsobom. To, že máš v jednej bunke základnú hodnotu, v druhej percento a v tretej vypočítanú hodnotu, je najlepší spôsob, ako to riešiť.

Pridaná hodnota takéhoto makra je nulová. Okrem toho, že používateľ musí povoliť makrá, aby mu to vôbec fungovalo, úplne zbytočne prichádzaš aj o možnosť Undo.

Keď už to chceš tak veľmi riešiť makrom, tak:
1. Vyhoď celý modul s funkciami CalculatePercentage a SetNewBase.
2. Uprav funkciu Workbook_Open v ThisWorkbook na:

Private Sub Workbook_Open()
    Sheet1.Initialize
End Sub

3. Do Sheet1 vlož nasledovný kód:

Private aPercentageNumbers() As PercentageNumber

Private Type PercentageNumber
    PercentageAddress As String
    NumberAddress As String
    BaseNumber As Variant
End Type

Public Sub Initialize()
    Dim aIndex As Integer
    
    ReDim Preserve aPercentageNumbers(1 To 2)
    
    With aPercentageNumbers(1)
        .PercentageAddress = "P16"
        .NumberAddress = "M16"
    End With
    
    With aPercentageNumbers(2)
        .PercentageAddress = "P17"
        .NumberAddress = "M17"
    End With
    
    For aIndex = LBound(aPercentageNumbers) To UBound(aPercentageNumbers)
        With aPercentageNumbers(aIndex)
            .BaseNumber = Range(.NumberAddress) / (1 - Range(.PercentageAddress))
        End With
    Next aIndex
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim aIndex As Integer

    Application.EnableEvents = False
    For aIndex = LBound(aPercentageNumbers) To UBound(aPercentageNumbers)
        With aPercentageNumbers(aIndex)
            If Not Intersect(Target, Range(.PercentageAddress)) Is Nothing Then
                Range(.NumberAddress).Value = .BaseNumber * (1 - Range(.PercentageAddress))
            End If
            If Not Intersect(Target, Range(.NumberAddress)) Is Nothing Then
                .BaseNumber = Range(.NumberAddress)
                Range(.PercentageAddress).Value = 0
            End If
        End With
    Next aIndex
    Application.EnableEvents = True
End Sub

4. Buď ručne spusti makro Initialize, alebo zošit ulož, zatvor a otvor.

Funguje mi to v CZ Excel 2007 a EN Excel 2010... na vícero počítačích. Těžko mi to debugovat.

Moas - veľmi si mi pomohol veľmi pekne ďakujem!

los, Siki83 - Vám tiež ďakujem za pomoc ale potrebujem to tak ako mi to Moas urobil! :)

Ešte raz vďaka a považujte to za vybavené

Jestli ti to hází pořád nějakou chybu, tak mi dej verzi Excelu, co máš a ještě se na to podívám.